Parabolic SAR

How to Read the Parabolic SAR Dots

The Parabolic SAR (Stop and Reverse) is a technical indicator used to identify potential reversals in an asset's price trend. While the visual dots plotted by the indicator are easy to interpret, understanding the underlying calculations is key to using it effectively. In this post, we'll dive deep into the Parabolic SAR code to truly grasp how it operates.

If you haven't already, I would recommend following along with our video tutorial for Part 1 of our Parabolic SAR video series, which is a good resource alongside this post:

The Parabolic SAR plots dots above or below the price action, indicating the potential trend direction.

• Dots below price action represent a bullish bias (cyan dots in our version)
• Dots above price action represent a bearish bias (pink dots in our version)

The primary purpose of the Parabolic SAR is to identify trend reversals.

When the dots switch positions relative to the price, it's a signal that the trend may be reversing. However, the indicator can also be used for trend continuation, as the dots continuing to plot in the same direction suggest that the existing trend is still healthy.

Code Walkthrough

To truly understand the Parabolic SAR, it's essential to examine the code that powers the indicator. Let's walk through the code step by step, to take a look under the hood!

Input Variables

The Acceleration Factor (AF) and Acceleration Limit (AL) are the two input variables that users can adjust from the study settings menu.

Think of the Acceleration Factor as the gas pedal, controlling the speed at which the indicator responds to price movements. The Acceleration Limit acts as the maximum speed, ensuring that the indicator's responsiveness doesn't exceed a certain threshold.

input accelerationFactor = 0.02;
input accelerationLimit = 0.2;

The code starts by defining two user input variables:

• accelerationFactor: This controls the initial acceleration or sensitivity of the indicator to price changes. The default value is 0.02. It acts as our "gas pedal" to control our car's speed.
• accelerationLimit: This sets the maximum acceleration allowed for the indicator, preventing over-sensitivity. The default value is 0.2. This is the max speed limit of our car.

Variable Initialization

def state = {default init, long, short};
def extreme;
def SAR; 
def acc;

The code then initializes four key variables:

1. state: A def (short for define) variable that can hold one of three values: "init", "long", or "short". This tracks the current indicator state.
2. extreme: A def variable that will store the highest or lowest price since the last state change.
3. SAR: A def variable that will hold the calculated SAR value to be plotted.
4. acc: A def variable that will track the current acceleration value.

Switch Function - Initialization State

The switch function is where the magic happens.

The core logic of the Parabolic SAR indicator is implemented in a switch function that updates the state and variables based on the price action.

case init:
state = state.long;
acc = accelerationFactor;
extreme = high;
SAR = low;

In the initialization case...

• The state is set to "long"
• acc is set to the user input accelerationFactor variable
• extreme is set to the current high price
• SAR is set to the current low price

This assumes the start of a potential uptrend.

Switch Function - Short State

In the short state, the code checks if the SAR value crosses below the current high price, indicating a potential trend reversal. If so, it switches to the long state and updates the relevant variables.

case short:
if (SAR[1] < high)
then {
state = state.long;
acc = accelerationFactor;
extreme = high;
SAR = extreme[1];
} else {
state = state.short;
if (low < extreme[1])
then {
acc = min(acc[1] + accelerationFactor, accelerationLimit);
extreme = low;
} else {
acc = acc[1];
extreme = extreme[1];
}
SAR = max(max(high, high[1]), SAR[1] + acc * (extreme - SAR[1]));
}

In the short case:

1. If the previous SAR value crosses above the current high price, it anticipates a trend reversal to long. The state is flipped, acc/extreme/SAR are reset.
2. Else, it means the short trend is continuing:
   • If the current low is lower than the previous extreme low, it increases acc (acceleration) up to the accelerationLimit as the downtrend is strengthening.
   • extreme is also updated to the new low.
   • If the current low is not lower than the previous extreme, acc and extreme are unchanged.
3. The new SAR value is calculated as the maximum of:
   • The current high price
   • The previous high price
   • The previous SAR plus the current acceleration multiplied by the difference between extreme and previous SAR

Switch Function - Long State

In the long state, the code checks if the SAR value crosses above the current low price. If it does, it anticipates a potential trend reversal and switches to the short state, resetting the acceleration and updating the extreme and SAR values accordingly.

case long:
if (SAR[1] > low)
then {
state = state.short;
acc = accelerationFactor;
extreme = low;
SAR = extreme[1];
} else {
state = state.long;
if (high > extreme[1])
then {
acc = min(acc[1] + accelerationFactor, accelerationLimit);
extreme = high;
} else {
acc = acc[1];
extreme = extreme[1];
}
SAR = min(min(low, low[1]), SAR[1] + acc * (extreme - SAR[1]));
}

The long case is essentially the inverse of the short case:

1. If the previous SAR value crosses below the current low price, it anticipates a trend reversal to short. The state is flipped, acc/extreme/SAR are reset.
2. Else, it means the long trend is continuing:
   • If the current high exceeds the previous extreme high, it increases acc (acceleration) up to the accelerationLimit as the uptrend is strengthening.
   • extreme is also updated to the new high.
   • If the current high does not exceed the previous extreme, acc and extreme are unchanged.
3. The new SAR value is calculated as the minimum of:
   • The current low price
   • The previous low price
   • The previous SAR plus the current acceleration multiplied by the difference between extreme and previous SAR

Plotting the PSAR Dots

Finally, the code plots the calculated SAR value on the chart using the plot function:

plot parSAR = SAR;
parSAR.SetPaintingStrategy(PaintingStrategy.POINTS);
parSAR.SetDefaultColor(GetColor(5));

The code plots the dots as points, and sets the default color, which we can use as a starting point for our indicator customization.

By this point, you should have a good understanding of how the Parabolic SAR indicator works behind the scenes, and all of the calculations that are taking place.

In the next section, we'll start by customizing the indicator, and make a BETTER version of the Parabolic SAR indicator.